||
Visual Basic与图像处理(三)
6、Roberts微分算子
前面介绍的两种微分算子,实际上是分别求出了水平和垂直方向上的细节信息。但在实际的图像处理之中,除了特殊用途之下才会使用到方向滤波,大部分二维图像处理时,需要同时获得两个方向上的细节信息,因此需要设计各向同性的微分算子用于图像的锐化处理。
Roberts算子一种常用的微分算子,可以满足上述要求,其计算方法可以用下面的公式进行表示:
同样上面的公式可以用下面的两个模板进行表示:
本例的运行界面如下图所示:
Roberts滤波按钮对应的代码如下:
Private Sub cmdRobertsFilter_Click()
Dim i As Integer, j As Integer
Dim PixelValue As Long
Dim r As Integer, g As Integer, b As Integer
Dim GrayValue As Integer
Dim Temp(1, 1) As Integer
Dim x As Integer, y As Integer
Dim Dx As Integer, Dy As Integer
Dim NGrayValue As Integer
'设置目标图像的高度和宽度
DestImHeight = SourceImHeight - 1 '边界像素直接不要了
DestImWidth = SourceImWidth - 1
'设置目标PictureBox的大小
PicDest.Height = DestImHeight
PicDest.Width = DestImWidth
ReDim dbits(DestImHeight - 1, DestImWidth - 1, 2) As Byte '重新定义目标数组的维数
dbits = sbits '数组的直接复制,只有数组维数完全一样才可以
'图像的Roberts滤波
For i = 0 To SourceImHeight - 2 '边界像素不处理
For j = 0 To SourceImWidth - 2
NGrayValue = 0
For x = 0 To 1
For y = 0 To 1
r = sbits(i + x, j + y, 0)
g = sbits(i + x, j + y, 1)
b = sbits(i + x, j + y, 2)
'插入图像处理的过程,对r, g, b进行处理
Temp(x, y) = 0.3 * r + 0.59 * g + 0.11 * b
Next y
Next x
Dx = -Temp(0, 0) + Temp(1, 1)
Dy = -Temp(0, 1) + Temp(1, 0)
NGrayValue = Abs(Dx) + Abs(Dy)
If NGrayValue > 255 Then NGrayValue = 255
dbits(i, j, 0) = NGrayValue
dbits(i, j, 1) = NGrayValue
dbits(i, j, 2) = NGrayValue
Next j
Next i
Dim tDBmpInfo As BITMAP
Dim hDestBmp As Long
hDestBmp = PicDest.Image.Handle
'获得位图信息
Call GetObject(hDestBmp, Len(tDBmpInfo), tDBmpInfo)
ReDim ImageArray(1 To DestImWidth * 4, 1 To DestImHeight) As Byte
For i = 1 To DestImHeight
For j = 1 To DestImWidth
ImageArray((j - 1) * 4 + 1, i) = dbits(i - 1, j - 1, 2)
ImageArray((j - 1) * 4 + 2, i) = dbits(i - 1, j - 1, 1)
ImageArray((j - 1) * 4 + 3, i) = dbits(i - 1, j - 1, 0)
Next j
Next i
'获得源图与目标图二进制位
Call SetBitmapBits(hDestBmp, tDBmpInfo.bmWidthBytes * tDBmpInfo.bmHeight, ImageArray(1, 1))
End Sub
Archiver|手机版|科学网 ( 京ICP备07017567号-12 )
GMT+8, 2024-5-17 08:21
Powered by ScienceNet.cn
Copyright © 2007- 中国科学报社